Воскресенье, 20.08.2017, 14:48

..



Главная Регистрация Вход
Приветствую Вас, Гость · Браузер: « v»
[ Новые сообщения · Участники · Правила форума · Поиск · RSS ]
Страница 1 из 11
Всё об «Электроника БК0010(-01), БК0011(М)»! » Языки программирования » Бейсик » Листинги игр » «Стена» [xx.xx.xx] (Автор: WSK corp. [Коренков В.С.])
«Стена» [xx.xx.xx]
-=RUS=-Дата: Пятница, 16.11.2012, 22:33 | Сообщение # 1
Генералиссимус
Группа: Администраторы
Сообщений: 350
Репутация: 1
Статус: Offline
;Листинг игры «Стена» на «Бейсике» для «БК0010-01»

10 DIM A(10,5),B(10,5)
20 IF PEEK(&O40)=0THEN? CHR¤(155)
30 COLOR 4,4
40 ? CHR¤(158)
50 COLOR 1,0
60 CLS
70 COLOR 1
80 LINE (128,40)-(128,40)
90 DRAW "R25F50D50G50L50H50U50E50R25"
100 COLOR 2
110 ? AT(14,8)"СТЕНА"
120 COLOR 2
130 ? AT(12,10)"¦¦ WSK ¦¦"
140 COLOR 3
150 ? AT(10,12)"авт.Коренков"
160 ? AT(12,14)"435-95-14"
170 FOR I=1TO15
180 BEEP
190 NEXT
200 COLOR 2
210 ? AT(4,22)"ИНСТРУКЦИЯ НУЖНА (D/N) ?";
220 D¤=INKEY¤
230 IF D¤="" THEN 220
240 IF D¤="D"THENGOSUB1160
250 FOR I=1TO10
260 FOR J=1TO5
270 A(I,J)=INT(RND(1)*32767)
280 IF J/10 290 NEXT J,I
300 G%=20
310 W%=50
320 B%=1
330 X%=1
340 Y%=1
350 CLS
360 COLOR 2
370 LINE (118,48)-(118,48),3
380 DRAW "R130D105L130U105"
390 J=X%
400 FOR I=1TO10
410 FOR C=1TO16
420 A=A(I,J)
430 GOSUB 1080
440 NEXT C,I
450 COLOR 2
460 ? AT(0,2)"¦¦¦¦¦¦¦¦¦¦¦¦ ¦¦¦¦¦¦¦¦¦¦¦"
470 ? AT(0,17)"¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦"
480 ? AT(0,7)"ЭТАЖ";X%
490 ? "ВОДА";W%
500 ? "ГРАНАТЫ";G%
510 ? "КЛАД";S%
520 ? "ВРЕМЯ";K%
530 K%=K%+1
540 W%=W%-1
550 IF I=10AND J=1AND B%=16ANDS%>=15THEN1450
560 IF W%=0THEN1560
570 A=B%
580 I=Y%
590 J=X%
600 COLOR 1
610 C=A
620 GOSUB 1080
630 ? AT(12,2)":ВАШ ХОД:"
640 H¤=INKEY¤
650 IF H¤=CHR¤(26) AND Y%=1THEN640ELSE IF H¤=CHR¤(26) THENYY%=Y%-1ELSE680
660 L%=B%
670 GOTO 920
680 IF H¤=CHR¤(27) AND Y%=10THEN640ELSE IF H¤=CHR¤(27) THENYY%=Y%+1ELSE 710
690 L%=B%
700 GOTO 920
710 IF H¤=CHR¤(25) AND B%=16THEN640ELSE IF H¤=CHR¤(25) THENL%=B%+1ELSE 740
720 YY%=Y%
730 GOTO 920
740 IF H¤=CHR¤(8) AND B%=1THEN640ELSE IF H¤=CHR¤(8) THENL%=B%-1ELSE 770
750 YY%=Y%
760 GOTO 920
770 IF H¤=CHR¤(19) AND X%=1THEN640ELSE IF H¤=CHR¤(19) THENX%=X%-1ELSE800
780 L%=B%
790 GOTO 350
800 IF H¤=CHR¤(10) AND X%=5THEN640ELSE IF H¤=CHR¤(10) THENX%=X%+1ELSE830
810 L%=B%
820 GOTO 350
830 IF H¤=" "THENPOKE&O326,A(YY%,X%)ELSE640
840 IF G%=0THEN640
850 FOR N=1TO10
860 BEEP
870 NEXT
880 G%=G%-1
890 GOSUB 1130
900 OUT &O326,F,0
910 A(YY%,X%)=PEEK(&O326)
920 POKE &O326,A(YY%,X%)
930 GOSUB 1130
940 IF INP(&O326,F)=0THEN970
950 ? AT(12,2)"¦:СТЕНА:¦"
960 GOTO 640
970 ? AT(14+B%,4+Y%);CHR¤(32)
980 B%=L%
990 Y%=YY%
1000 ? AT(14+B%,4+Y%);CHR¤(127)
1010 POKE &O326,B(YY%,X%)
1020 GOSUB 1130
1030 IF INP(&O326,F) THENOUT&O326,F,0ELSE1070
1040 B(YY%,X%)=PEEK(&O326)
1050 IF X%=5THENS%=S%+1
1060 IF RND(1)>.5THENW%=W%+4ELSEG%=G%+1
1070 GOTO 450
1080 POKE &O326,A
1090 F=INT(2^(C-1)+0.1)
1100 IF F=32768THENF=16884
1110 IF INP(&O326,F)THEN?AT(14+C,4+I);CHR¤(127)
1120 RETURN
1130 F=INT(2^(L%-1)+.1)
1140 IF F=32768THENF=16884
1150 RETURN
1160 CLS
1170 COLOR 1
1180 ? AT(10,0)"'СТЕНА'"
1190 COLOR 2
1200 ? "Цель игры заключается в том, чтобы перемещаясь по лабиринту"
1210 ? "собрать как можно больше сокровищ ."
1220 ? "Вы управляете красным квадратом.После пуска вы находитесь"
1230 ? "на первом этаже ,сокровища лежатна пятом,на остальных"
1240 ? "этажах есть тайники с динамитом и водой,пополнить запасы"
1250 ? "которых вы можете найдя их. Истратив воду вы гибните."
1260 ? "Выход из лабиринта находится в правом нижнем углу первого"
1270 ? "этажа лабиринта,однако выйти из лабиринта можно лишь найдя"
1280 ? "не менее 10 кладов."
1290 COLOR 1
1300 ? AT(0,23)"НАЖМИТЕ ЛЮБУЮ КЛАВИШУ";CHR¤(7);
1310 COLOR 2
1320 IF INKEY¤="" THEN 1320
1330 CLS
1340 ? "Клавиши управления: налево(¦), направо(+),вверх(Ё),вниз(-),"
1350 ? "переход на нижний этаж(ВВОД),на верхний(ВС)."
1360 ? "После перехода на другой этаж нажмите любую управляющую"
1370 ? "клавишу,для того чтобы определить свое положение"
1380 ? "Взрывают стену так:делают ход в сторону стены,которую хотят"
1390 ? "взорвать,наверху загорается 'стена',затем нажимают <ПРОБЕЛ>."
1400 COLOR 1
1410 ? AT(0,23)"НАЖМИТЕ ЛЮБУЮ КЛАВИШУ";CHR¤(7);
1420 COLOR 2
1430 IF INKEY¤="" THEN 1430
1440 RETURN
1450 CLS
1460 IF RND(1)<.2THEN1510
1470 ? AT(11,2)"ПОЗДРАВЛЯЮ!"
1480 ? AT(1,4)"Вы нашли клад на сумму:";S%*1000;"D"
1490 ? AT(5,6)"Затрачено времени:";K%;"сек"
1500 GOTO 1610
1510 ? AT(11,2)"СОЧУВСТВУЮ!"
1520 ? AT(4,4)"По выходе из лабиринта под"
1530 ? AT(4,5)"тяжестью сокровищ лесница"
1540 ? AT(4,6)"рухнула вы погибли."
1550 GOTO 1610
1560 CLS
1570 ? AT(13,2)"СОЖАЛЕЮ!"
1580 ? AT(4,4)"У вас кончились запасы воды"
1590 ? AT(4,5)"вы обречены на мучительную"
1600 ? AT(4,6)"медленную смерть."
1610 FOR I=0 TO 20
1620 BEEP
1630 NEXT
1640 ? CHR¤(158)
1650 END


 
Всё об «Электроника БК0010(-01), БК0011(М)»! » Языки программирования » Бейсик » Листинги игр » «Стена» [xx.xx.xx] (Автор: WSK corp. [Коренков В.С.])
Страница 1 из 11
Поиск:

-=RUS=-
ICQ: 320867225